Hello Sandrine,
for a single object deletion, there would be no problem to do what you want (we can easily manage the "delete" menu for an object). Unfortunately there is no way, as far as I know, to manage the delete menu on a multiple collection of objects.
But, since you said your objects to delete are connected to a specific keyword, you could run the delete from the keyword menu ! To do so :
Create a metaCommand on the keyword metaclass
Create a macro attached to this metaCommand coded like this (to be adapted to your real need) :
Sub CmdInvoke(oKeyword, intCmdNumber)
Dim oRoot, fso, strFile, myFile, myMode, i
Dim oObjectToDelete, colObjectsToDelete
Dim strIdCurrentMetaclass, strIdApplication, strIdUIM, strIdIHMC
Set oRoot = oKeyword.getRoot
Set fso = CreateObject("Scripting.FileSystemObject")
strFile = "C:\Temp\ObjectsToExclude.txt" 'path & name of file where _hexaIdAbs will be written
myMode = 8 '2 if you want to overwrite the file each time you delete objects
Set myFile = fso.OpenTextFile(strFile, myMode, True)
'Collection des Keywords elements à supprimer
Set colObjectsToDelete = oKeyword.getCollection("~QNBAAlJF9bM2[Keyword Element]")
'To delete all objects, and not only one on two
'we start by the end of the collection
For i = colObjectsToDelete.count to 1 Step -1
set oObjectToDelete = colObjectsToDelete.Item(i)
strIdCurrentMetaclass = oRoot.getObjectFromid(oObjectToDelete.getId).getClassId
strIdApplication = oRoot.getObjectFromid("~MrUiM9B5iyM0[Application]").getId
strIdUIM = oRoot.getObjectFromid("<Id for the UIM metaclass>").getId
strIdIHMC = oRoot.getObjectFromid("<id for the IHMC metaclass>").getId
'_HexaIdAbs are needed only in certain cases...
If strIdCurrentMetaclass = strIdApplication OR strIdCurrentMetaclass = strIdUIM OR _
strIdCurrentMetaclass = strIdIHMC Then
Call myFile.WriteLine(oObjectToDelete.getProp("~H20000000550[_HexaIdAbs]"))
End If
'All objects linked to the keword are deleted...(not only "Application" "UIM" and "IHMC")
oObjectToDelete.delete("NOHIERARCHY")
Next
Set myFile = Nothing
Set fso = Nothing
End Sub
'If the "Delete" menu must appear only on the specific keyword
'manage it here
Sub CmdCheck(mgobjSource, intCmdNumber, intStatusReturned)
intStatusReturned = 512
If mgobjSource.getProp("~H20000000550[_HexaIdAbs]") = "<_HexaIdabs of the specific keyword>" Then
intStatusReturned = 0
End If
End Sub
If it is not what you wanted, just tell me 🙂
Lionel
